ドリル作成ツール

ドリル作成ツール　VB6

　３．共通処理

　オブジェクト（部品）と関係しない処理で、ドリル作成ツールで共通に利用できるプロシージャである。
　次のようにして追加した標準モジュールにプログラムする。標準モジュールのオブジェクト名をDrillSub、ファイル名をDrillSub.BASとしている。
　　　　［プロジェクト(P)］ → ［標準モジュールの追加(M)］　　→　　標準モジュール
　ほかのテーマのドリル作成ツールをプログラムするときは、このDrillSub.BASを追加すればよい。

前提条件　　オリジナルの問題データ（BTextｉに記憶させるデータ）に関して
(1) 問題と解答の区切りとして"#-----解答-----"が1行挿入されている。また、データの最後の印に"##"が挿入されている。
(2) 問題と解答のデータには、各問([1]など)の後に"ア"(半角のア)、各問題(【１】など)の後に"イ"(半角のイ)が付けてある。
　【】、[]や半角カタカナを目印にHTMLのタグを挿入している。半角カタカナはブラウザで表示するのに適さない文字なので目印として利用している。
(3) 表示すべき半角空白はすべて   に置き換えるので、 に置き換えたくない半角空白は"ウ"(半角のウ)で表す。

プロシージャの一覧

	定数の定義とグローバル変数の宣言
テキスト整形	Public Function Text2HTMLjs(ByVal ptext As String) As String	テキストをHTML化(JAVAScript付き)
	Private Function KaiLen(pt As Long, txt As String) As Integer	解答の文字数を返す。
	Private Function GetKai(pt As Long, txt As String) As String	解答を返す。
	Public Function Text2HTML(ByVal ptext As String) As String	テキストをHTML化
	Public Function Text2Text(ByVal ptext As String) As String	テキスト化
設定ファイル	Public Sub ReadHTML()	HTMLデータ読み込み
	Public Function iniFileRead(fname As String, keyw As String) As String	iniファイルの読み込み
	Public Sub iniFileWrite(fname As String, keyw As String, dat As String)	iniファイルへの書き込み
ファイル操作	Public Function BaseName(ByVal fname As String) As String	ファイル名の取得
	Public Function PathName(ByVal fname As String) As String	パス名の取得
	Public Function isFile(fname As String) As Boolean	ファイルの存在の有無を返す
乱数	Public Sub InitRansuu(nn As Long)	同じ乱数系列のための初期化


	Public Function Ransuu(min As Long, max As Long) As Long	指定範囲の整数の乱数を返却する。
	Public Sub RansuuN(ko As Integer, arry() As Double, min As Long, max As Long)	指定範囲の整数の乱数を複数個作成する。
基数変換	Public Function Dec2Hex(ByVal dat As Double) As String	10→16進数文字列変換
	Public Function Hex2Dec(ByVal dat As String) As Double	16→10進数文字列変換
	Public Function Dec2Bin(ByVal dat As Double) As String	10→2進数文字列変換
	Public Function Bin2Dec(ByVal dat As String) As Double	2→10進数文字列変換

定数の定義とグローバル変数の宣言

Option Explicit

'グローバル
'－＝－＝－　定数　－＝－＝－
Public Const COPYRIGHT As String = "Copyright (C) 2003 Hiroshi Masuda"
Public Const KAKKO1 As String = "【】"
Public Const KAKKO2 As String = "[]"
Public Const DQ As String = """"
'－＝－＝－　変数　－＝－＝－
Public MainForm As Object       'メインフォーム
Public TChangeF As Boolean      'テキスト(問題)変更有り／無しフラグ
Public BText As String          'テキスト(問題)オリジナル保存
Public USAGE As String          '使用法
'sHTML(1)=先頭、sHTML(0)=JAVAScript、sHTML(2)=中間、sHTML(3)=最後
Public sHTML(3) As String       'HTMLデータ[1023][123] ,(0)=script data
Public aFolder As String        'アプリフォルダ
Public sFolder As String        '作業フォルダ
Public IniFile As String        'アプリ用INIファイル

　配列sHTMLには、挿入用のHTMLタグを記憶させる。sHTML(0)はJAVAスクリプト(解答チェックなど)、sHTML(1)は<HTML>などの先頭部分、sHTML(2)は<BODY>などの中間部分、sHTML(3)は</HTML>などの最終部分である。HTML(表示)には配列sHTMLの(1)(2)(3)を、HTML(自習)には配列sHTML(1)(0)(2)(3)を挿入する。
　配列sHTMLに記憶させるHTMLタグは"DrillSub.ini"ファイルに用意する。ファイルの内容については次のページで説明する。

Text2HTMLjs　…　テキストをHTML化(JAVAScript付き)

Public Function Text2HTMLjs(ByVal ptext As String) As String
'--=*=----=*=----=*=----=*=----=*=--
'テキストをHTML化(JAVAScript付き)
'　引数：ptext(String型)　…　テキストデータ(問題)
'　返却値：String型　…　HTMLタグが挿入されたデータ
'
'　問題と解答の境界に "#--" 、解答の終わりに "##" をデータとして入れておく。
'　画像ファイル名は "IMG=filename" の形式とする。filenameは""ではさまない。
'--=*=----=*=----=*=----=*=----=*=--
    Dim sdat As String, kai As String, wk As String
    Dim mnum As String, tag As String, list As String
    Dim pt As Long, ptk As Long, klen As Integer

    If ptext = "" Then
        Text2HTMLjs = ""
        Exit Function
    End If
    '問題と解答分割
    pt = InStr(ptext, "#--")    '解答開始
    kai = Mid(ptext, pt)            '解答データ
    sdat = Left(ptext, pt - 1)      '問題データ
    'TAG挿入
    pt = InStr(sdat, Left(KAKKO1, 1))   'FORMタグ（"【"を探してFORMタグを挿入）
    Do Until pt = 0
        mnum = "m" & Trim(Str(Val(Mid(sdat, pt + 1))))  '問題データから問題番号取得
        tag = "<FORMｳname=" & DQ & mnum & DQ & ">"
        sdat = Left(sdat, pt - 1) & tag & Mid(sdat, pt)
        pt = InStr(pt + Len(tag) + 1, sdat, Left(KAKKO1, 1))
    Loop
    pt = InStr(sdat, "ｱ")               'INPUTタグ 解答欄（半角のアを探してINPUTタグを挿入）
    ptk = InStr(kai, "ｱ")
    klen = KaiLen(ptk, kai)
    Do Until pt = 0        '↓DO-LOOP内の半角のウは空白の意味である。
        tag = " → <INPUTｳsize=" & DQ & Trim(Str(klen)) & DQ & "ｳtype=" & DQ & "text" & DQ & ">ｳ"
        tag = tag & "<INPUTｳsize=" & DQ & "3" & DQ & "ｳtype=" & DQ & "text" & DQ & "ｳvalue=" & DQ & DQ & ">"
        sdat = Left(sdat, pt - 1) & tag & Mid(sdat, pt)
        pt = InStr(pt + Len(tag) + 1, sdat, "ｱ")
        ptk = InStr(ptk + 1, kai, "ｱ")
        klen = KaiLen(ptk, kai)
    Loop
    pt = InStr(kai, Left(KAKKO1, 1))   'BUTTONタグ（解答チェックと正解ボタン及び処理の作成）
    mnum = "m" & Trim(Str(Val(Mid(kai, pt + 1))))   '解答データから問題番号取得
    ptk = InStr(pt + 1, kai, vbCrLf)
    wk = Mid(kai, pt + 1, ptk - pt)
    Do Until pt = 0
        tag = "<BR><BR><INPUTｳtype=" & DQ & "button" & DQ & "ｳvalue=" & DQ & "解答チェック" & DQ
        tag = tag & "ｳonclick=" & DQ & "ans=newｳArray("
        list = ""
        ptk = InStr(wk, "ｱ")
        Do Until ptk = 0    '解答リスト作成
            list = list & "'" & GetKai(ptk, wk) & "',"
            ptk = InStr(ptk + 1, wk, "ｱ")
        Loop
        list = Left(list, Len(list) - 1)
        tag = tag & list & ");"
        tag = tag & "ｳAnswerCheck(document." & mnum & ",ｳans,ｳ0);" & DQ
        tag = tag & "> <INPUTｳname=" & DQ & "ten" & DQ & "ｳsize=" & DQ & "3"
        tag = tag & DQ & "ｳtype=" & DQ & "text" & DQ & "ｳvalue=" & DQ & DQ & ">点    "
        tag = tag & "↓ｳ<INPUTｳtype=" & DQ & "button" & DQ & "ｳvalue=" & DQ & "正　解" & DQ
        tag = tag & "ｳonclick=" & DQ & "ans=newｳArray(" & list & ");ｳAnswerDisplay(document."
        tag = tag & mnum & ".kai,ｳans);" & DQ & "><BR><TEXTAREAｳrows=" & DQ & "3" & DQ
        tag = tag & "ｳcols=" & DQ & "50" & DQ & "ｳname=" & DQ & "kai" & DQ
        tag = tag & "ｳreadonly></TEXTAREA></FORM>"
        ptk = InStr(pt, sdat, "ｲ")   '↓BUTTONタグの挿入（半角のイを探して挿入）
        sdat = Left(sdat, ptk - 1) & tag & Mid(sdat, ptk + 1)
        pt = InStr(pt + 1, kai, Left(KAKKO1, 1))
        mnum = "m" & Trim(Str(Val(Mid(kai, pt + 1))))   '問題番号
        ptk = InStr(pt + 1, kai, vbCrLf)
        wk = Mid(kai, pt + 1, ptk - pt)
    Loop
    
    sdat = Text2HTML(sdat)
    pt = InStr(sdat, "</HEAD>")
    sdat = Left(sdat, pt - 1) & sHTML(0) & Mid(sdat, pt)    'script挿入
    pt = InStr(sdat, "ｳ")   'ｳ
    Do Until pt = 0    '半角のウを空白に変換
        sdat = Left(sdat, pt - 1) & " " & Mid(sdat, pt + 1)
        pt = InStr(pt + 1, sdat, "ｳ")
    Loop
    Text2HTMLjs = sdat      '返却値
End Function

　KaiLenプロシージャは解答部分の文字数(長さ)を返却する。GetKaiプロシージャは解答部分を返却する。
　Text2HTMLプロシージャは問題と解答のデータにHTML(表示)用のタグを挿入する処理である。